Default Shadow
The following is the default background property value for all uiWindow instances:
{shadow_up:0x000000, shadow_up_maximized:-1};
That tells the instance it should render a drop shadow of color 0×000000 when its visual state is “up”, and not render any drop shadow when its visual state is “up_maximized” (when it is maximized, the drop shadow cannot be seen so applying the effect will be pointless).

Always Cast Drop Shadow
To make a uiWindow instance always cast a drop shadow, you can set its background property as below:

var win:uiWindow = new uiWindow();
win.background = {shadow:0x000000};

Never Cast Drop Shadow
To make a uiWindow instance never cast a drop shadow, you can set its background property to null:

var win:uiWindow = new uiWindow();
win.background = null;

Glow Effect
As of v1.3.0+, you can also get the uiWindow instance (any uiComponent, actually) to cast a glow effect:

var win:uiWindow = new uiWindow();
win.background = {glow_up:0x000000, glow_up_maximized:-1};

Drop Shadow + Glow
In the “vista” theme, the uiWindow instances use drop shadow + glow effects:

See: “vista” themed uiWindow demo

Specifying Default uiWindow Background Property
If you wish to override the default background property value, ie set the default value for all uiWindow instances, you can do so by defining it in the theme folder’s “rules.xml”:

<Window edge="5,5,5" slices="up,out,up_maximized,out_maximized" prefs="padding|5|background|shadow_up,0,shadow_up_maximized,-1,glow,0,glowDepth,12,glow_up_maximized,-1" />

Aspire UI Components
Aspire UI is a library of Actionscript 3.0 (AS3) classes for building flexible and lightweight UI elements in Adobe Flash applications. Key features include easy skinning using PNG image files, automatic tab focus ordering, CSS text styles, and layout management. This is a pure AS3 library with no dependency on the Flex framework.

You may experiment with the various features by downloading the trial version.

First, set up the TextField:

// ActionScript 3.0
var txt:TextField = new TextField();
// new TextFormat(font, size, color)
txt.defaultTextFormat = new TextFormat("DejaVu Sans", 21, 0xFFFFFF);
txt.antiAliasType = AntiAliasType.ADVANCED;
txt.autoSize = TextFieldAutoSize.LEFT;
txt.text = "The quick brown fox jumps over the lazy dog.";
txt.x = 5;
txt.y = 5;
addChild(txt);

Drawing The Outline
To draw an outline around the text glyphs, use the flash.filters.GlowFilter:

// new GlowFilter(color, alpha, blurX, blurY, strength)
txt.filters = [new GlowFilter(0x000000, 1.0, 2, 2, 4)];

Adjusting The Outline Thickness
To thicken the outline, increase the values for “blurX”, “blurY” and “strength”. The value of “blurX”/”blurY” should be the same. You can try various values to suit your needs, but the value of “strength” should be kept at double that of “blurX”/”blurY”. For example, if I were to use value of 4 for “blurX”/”blurY”, I would set “strength” as 8. Setting “strength” too low will cause blurring to be visible; setting it excessively high and the outline may become distorted.

// new GlowFilter(color, alpha, blurX, blurY, strength)
txt.filters = [new GlowFilter(0x000000, 1.0, 4, 4, 8)];

Aspire UI
If you are using the Aspire UI library, this feature is already built-in via the uiTextStyles manager:
http://ghostwire.com/aspireui/docs/textstyles/outline-and-shadow
The “outlineWeight” text style property (v1.2.2+) determines the thickness of the outline.

To apply one or more of these image filter effects to a display object, set the filters property of the respective DisplayObject instance to an Array containing the filter object(s).

Single Effect
For example, to give a Sprite a drop shadow:

var sp:Sprite = new Sprite();
sp.graphics.beginFill(0x0000FF);
sp.graphics.drawRect(0,0,20,20);
sp.graphics.endFill();
 
sp.x = 10;
sp.y = 10;
addChild(sp);
 
sp.filters = [new DropShadowFilter()]; // flash.filters.DropShadowFilter

To give the Sprite a glow effect:

sp.filters = [new GlowFilter()]; // flash.filters.GlowFilter

Take note that after setting the filters property to an array, modifying the array itself will have no effect on the display object. In order to modify the filter effects on the display object, you must set the filters property:

sp.filters = [new DropShadowFilter()];
sp.filters[0] = new GlowFilter(); // NO EFFECT!
sp.filters = [new GlowFilter()];

Composite Effect
If you are applying more than one effect to the same instance, take careful note of the index order of the filter objects in the array. The effects are applied in the same order as their index order in the array, ie the filter object in index position 0 is applied first, followed by the filter in position 1, and so on. Swapping the positions of the filter objects in the array will obviously give you different results.

sp.filters = [new GlowFilter(), new DropShadowFilter()]; // Glow, followed by DropShadow

If we change the positions:

sp.filters = [new DropShadowFilter(), new GlowFilter()]; // DropShadow, followed by Glow

Notice that the Glow now wraps around the DropShadow as well, because the drop shadow is drawn first, and so when the glow is drawn, it is rendered around the whole image which includes the drop shadow.

Therefore, when applying multiple image filter effects to the same display object, always take careful note of their index order in the filters array.

Adobe Flash IDE
The above applies when setting filters during run-time via ActionScript. If you are creating artwork using the Adobe Flash authoring IDE and applying filters via the Filters Panel, you can adjust the order of the effects by moving a filter up/down the list in the panel (click-and-hold on a filter, then drag and move it up/down to change its position in the list).

Reminder:
The cacheAsBitmap property of a display object is automatically set to true whenever you apply a filter to it (when its filters property is not null), ie thecacheAsBitmap property is reported as true for that display object, even if you set the property to false. If you clear all filters for a display object, the cacheAsBitmap setting changes to what it was last set to.

Set up the TextField:

// ActionScript 3.0
var txt:TextField = new TextField();
// new TextFormat(font, size, color, bold)
txt.defaultTextFormat = new TextFormat("DejaVu Sans", 21, 0x000000, true);
txt.embedFonts = true; // the font must be embedded
txt.antiAliasType = AntiAliasType.ADVANCED;
txt.autoSize = TextFieldAutoSize.LEFT;
txt.selectable = false;
txt.text = "The quick brown fox jumps over the lazy dog.";
txt.x = 5;
txt.y = 5;
addChild(txt);

Embossed Text
To apply an embossed text effect, use the flash.filters.BevelFilter:

txt.filters = [new BevelFilter(1.5, 45)]; // distance, angle

Engraved Text
To apply an engraved text effect, ie having the text look like it is etched into the surface, rotate the bevel angle by 180 degrees:

txt.filters = [new BevelFilter(1.5, 225)]; // distance, angle

The first parameter of the BevelFilter is the bevel distance – you can try various values, but I have found 1.5 to work well for most font sizes, to give the text a subtle yet visible embossed/engraved look.

Do bear in mind that in order for the effects to be visible, there must be reasonable amount of painted area on the text glyphs. If you use a small, thin font, then the effects are not going to be very visible. On the other hand, using a large, bold font is going make the effect more obvious.

If you are going to use the same filter(s) in multiple places, consider placing the filter(s) in a constant:

private const embossFilter:BevelFilter = new BevelFilter(1.5, 45);
private const engraveFilter:BevelFilter = new BevelFilter(1.5, 225);

You can then apply the filter as follows:

txt.filters = [embossFilter];

NOTE:
Notice that in the example above, the “selectable” property of the TextField instance is set to “false”. This is not really necessary, but it is important to note if the property is left as “true”, ie the text if left selectable, then when the text is selected, the portion that is selected loses the embossed/engraved effect. This is because the BevelFilter is applied to the TextField as a whole, not each alphabet individually – when there is a selection, and the background is highlighted (painted), the filter is applied to the background rather than the text in the foreground.