In my opinion, this menu does not add any functionality to any Flash application, is as useless as the built-in contextMenu items, and should always be hidden. Luckily, it takes only one line of code to hide the menu.

To hide the native menu bar, set the showDefaultContextMenu property of the stage object to false:

stage.showDefaultContextMenu = false;

You will need to ensure that the stage object is available, so the best place to do this is after your top-level container has been added to the display list:

package 
{
	import flash.display.Sprite;
	import flash.events.Event;
 
	public class Module extends Sprite 
	{
		public function Module()
		{
			if (stage) init();
			else addEventListener(Event.ADDED_TO_STAGE, init);
		}
 
		private function init(e:Event = null):void 
		{
			removeEventListener(Event.ADDED_TO_STAGE, init);
 
			// ** actual application code begins **
			// ** stage is no longer null **
			stage.showDefaultContextMenu = false;
		}
	}	
}

With that done, the SWF will no longer display the menu bar at the top when it is run locally:

Adobe’s documentation indicates that the showDefaultContextMenu property determines whether the default items in the Flash Player context menu should be shown or hidden. In actual fact, setting the property to false hides
(i) the built-in context menu items (except for the “Settings” and “About Adobe Flash Player” menu items);
AND
(ii) the native menu bar.

That makes the name of the property quite a misnomer, with no allusion to the fact that it can be used to hide the menu bar.

Well, I guess it would be too cumbersome to call it “showDefaultContextMenuAndNativeMenuBar”…

In my opinion, the native right-click context menu is an odd legacy from the Flash Movies days. It may be useful when Flash is used as a video player, for animations and cartoons, in the absence of any proper custom UI.

If you are developing Flash applications, you should consider always hiding the native right-click Flash Player context menu’s built-in items. Sure, you cannot get rid of the context menu completely, but you should at least hide the built-in items. It makes the application look a lot more professional because the long list of built-in items are mostly irrelevant.

If you don’t do anything about it, when end-users right-click on your Flash application, the pop-up context menu will show “Zoom In”, “Zoom Out”, “Show All”, “Quality” (and sub menu), and “Print…” – all of these should be done in-application via properly designed user interface if the application allows these features to begin with.

For example, allowing end-users to zoom in/out without designing the application to handle these adjustments properly can be detrimental to the user experience. And if your application handles zooming in/out, it should have the proper UI to convey the feature to end-users rather than depending on the right-click menu.

Likewise, “Quality” adjustment is something that should be done in-application via a proper Options dialog where graphics, sounds, and perhaps other application-specific options are made available.

For multiple-frame SWFs (such as would be the case if you have a preloader frame), the built-in context menu items will also include, in addition to those mentioned above, “Play”, “Loop”, “Rewind”, “Forward” and “Back” – none of which should be of any relevance to RIAs. Letting the end-user activate any of these frame-manipulation actions can potentially mess up your application.

HTML
You can get rid of the built-in context menu items via the HTML container page, by defining the Flash object’s “menu” parameter as “false”. If you are developing using the Adobe Flash IDE, you can generate the proper HTML page by unchecking the “Display Menu” option in the File -> Publish Settings dialog (HTML tab). If you are developing using FlashDevelop, the “menu” parameter is already set to “false” by default.

However, using this method, you are depending on the HTML container page to tell the SWF to hide the context menu’s built-in items – if the SWF is run outside the HTML page, the menu items will no longer be hidden. If you cannot guarantee that the SWF will be run within the HTML page you have generated, this method will not work well. For example, if you are developing a Flash widget whereby only the SWF itself will be distributed, the menu items will not be hidden if the SWF is ultimately shown standalone, or within a HTML page where the “menu” parameter of the Flash object is not set to “false”.

ActionScript
You can hide the built-in items of the native context menu by inserting just two lines of code:

contextMenu = new ContextMenu();
contextMenu.hideBuiltInItems();

You would typically insert the code into your top-level AS3 class as follows:

package 
{
	import flash.display.Sprite;
	import flash.ui.ContextMenu;
 
	public class Main extends Sprite 
	{		
		public function Main()
		{
			contextMenu = new ContextMenu();
			contextMenu.hideBuiltInItems();
		}
	}	
}

Note: the “contextMenu” property is implemented by the flash.displayObject.InteractiveObject class.
Main -> Sprite -> DisplayObjectContainer -> InteractiveObject

In the above code, you are setting the “contextMenu” property of the top-level Main class instance to a new ContextMenu instance (where the built-in items are hidden).

Using this method, the instructions are internal to the SWF itself. Whether the SWF is distributed and run standalone, or run within a HTML page, the built-in items will be hidden. Also, regardless of the value of the “menu” parameter of the containing HTML page, the built-in items are going to be hidden (ie setting the “menu” parameter to “true” in the HTML page will not override this).

With the built-in menu items hidden, when the end-user right-clicks on your Flash application, the pop-up context menu will show only two items – “Settings…” and “About Adobe Flash Player…” – concise, sleek, a lot more professional looking.

This example was implemented using uiMenu from the ActionScript 3.0 Aspire UI library.

Live demo:

• Pressing the mouse down anywhere on the dark area and holding it down, stationary, for half a second (500ms) will bring up a context menu.
• If the CTRL KEY check box is selected, pressing the mouse down anywhere on the dark area while holding down the CTRL-KEY will bring up the context menu (without waiting for 500ms).
• In this example, we have used 500ms for the delay – you can use another value in your own code, although 500ms is probably best for usability.

Here is the code:

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148

package
{
	import com.ghostwire.ui.containers.*;
	import com.ghostwire.ui.controls.*;
	import com.ghostwire.ui.data.*;
	import com.ghostwire.ui.events.*;
	import com.ghostwire.ui.enums.*;
	import com.ghostwire.ui.managers.*;
 
	import flash.display.Sprite;
	import flash.display.DisplayObject;
	import flash.events.*;
	import flash.system.Capabilities;
	import flash.utils.Timer;
 
	public class ContextMenuDemo extends Sprite
	{
		// ** instances **
		private var longPressTimer:Timer;
		private var popupMenu:uiMenu;		
		private var menuModel:uiModel;
		private var ctrlKeyCheck:uiCheckBox;
		private var displayText:uiText;
 
		private var longPressDelay:int = 500; // ** delay of 500ms **
 
		public function ContextMenuDemo()
		{
			addEventListener(Event.ADDED_TO_STAGE,init);
		}
 
		private function init(evt:Event):void
		{
			uiSkins.initialize("classic"); // ** using "classic" theme **
			uiSkins.manager.addEventListener(Event.INIT,main);
		}
 
		private function main(evt:Event):void
		{
			// ** main application code **
 
			// ** create a hotspot on the stage **
			var hotspot:Sprite = new Sprite();
			hotspot.graphics.beginFill(0,0.2);
			hotspot.graphics.drawRect(0,0,200,200);
			hotspot.graphics.endFill();
			hotspot.x = 50;
			hotspot.y = 50;
			addChild(hotspot);
			hotspot.addEventListener(MouseEvent.MOUSE_DOWN,on_startTimer,false,0,true);
			hotspot.addEventListener(MouseEvent.MOUSE_MOVE,on_cancelTimer,false,0,true);
			hotspot.addEventListener(MouseEvent.MOUSE_UP,on_cancelTimer,false,0,true);
 
			// ** toggle CTRL key trigger **
			ctrlKeyCheck = new uiCheckBox("CTRL KEY");
			ctrlKeyCheck.move(50,250);
			addChild(ctrlKeyCheck);
 
			// ** display text for reporting menu choice **
			displayText = new uiText();
			addChild(displayText);
 
			// ** popup menu XML **
			var menuXML:XML =
			<menu>
			<item label="View">
				<item label="Large Icons"	group="iconsize" />
				<item label="Medium Icons"	group="iconsize" />
				<item label="Classic Icons"	group="iconsize"  checked="true" />
				<item />
				<item label="Auto Arrange"	checked="false" />
				<item label="Align to Grid"	checked="true" />
			</item>
			<item label="Sort By">
				<item label="Name" />
				<item label="Size" />
				<item label="Type" />
				<item label="Date Modified" />
			</item>
			<item />
			<item label="Refresh" />
			<item />
			<item label="Help" />
			</menu>
 
			// ** menu model using the XML **
			menuModel = new uiModel(menuXML);
		}
 
		private function showPopup():void
		{
			popupMenu = uiMenu.popup(menuModel,stage);
			popupMenu.addEventListener(uiMenuEvent.MENU_SELECT,on_menuSelect,false,0,true);
		}
 
		private function on_cancelTimer(evt:MouseEvent):void
		{
			if (longPressTimer)
			{
				displayText.text = "long press cancelled";
				// ** cancel long press timer **
				longPressTimer.removeEventListener(TimerEvent.TIMER,on_timer);
				longPressTimer.stop();
				longPressTimer = null;
			}
		}
 
		private function on_startTimer(evt:MouseEvent):void
		{
			if (ctrlKeyCheck.selected && (evt.ctrlKey))
			{
				showPopup();
			}
			else
			{
				displayText.text = "pressing...";
				// ** create a timer for detecting long press **
				if (longPressTimer == null)
				{
					longPressTimer = new Timer(longPressDelay);
				}
				else
				{
					longPressTimer.reset();
				}
				// ** start long press timer **
				longPressTimer.addEventListener(TimerEvent.TIMER,on_timer,false,0,true);
				longPressTimer.start();
			}
		}
 
		private function on_timer(evt:TimerEvent):void
		{
			displayText.text = "popup menu shown";
			longPressTimer.removeEventListener(TimerEvent.TIMER,on_timer);
			longPressTimer.stop();
			longPressTimer = null;
			showPopup();
		}
 
		private function on_menuSelect(evt:uiMenuEvent):void
		{
			displayText.text = "Label: "+evt.item.label+" has been selected";
			displayText.text += "\ngroup property value: "+evt.item.group;
			displayText.text += "\nchecked property value: "+evt.item.checked;
		}
	}
}

Notes:

• We start the timer when the mouse is pressed down on the hotspot, and cancel the timer if the mouse is moved or released.

50
51
52

			hotspot.addEventListener(MouseEvent.MOUSE_DOWN,on_startTimer,false,0,true);
			hotspot.addEventListener(MouseEvent.MOUSE_MOVE,on_cancelTimer,false,0,true);
			hotspot.addEventListener(MouseEvent.MOUSE_UP,on_cancelTimer,false,0,true);

• If the CTRL KEY check box is selected, we want to show the popup menu immediately when the mouse is pressed down so the timer is not used:

108
109
110
111
112
113
114
115
116

		private function on_startTimer(evt:MouseEvent):void
		{
			if (ctrlKeyCheck.selected && (evt.ctrlKey))
			{
				showPopup();
			}
			else
			{
				...

• The static uiMenu.popup() method takes two parameters:
  uiMenu.popup(model,context);
  The “model” parameter is the uiModel object that will be used to populate the popup menu.
  The “context” parameter can be any DisplayObject on the stage. The popup menu will be positioned below this “context” (or above if necessary). If this parameter is set to the stage (as is the case in this example), the current mouse position when the method is called will be used when deciding where to place the popup menu.

90
91
92
93
94

		private function showPopup():void
		{
			popupMenu = uiMenu.popup(menuModel,stage);
			popupMenu.addEventListener(uiMenuEvent.MENU_SELECT,on_menuSelect,false,0,true);
		}

• The uiMenu.popup() method returns a reference to the uiMenu that is shown. The uiMenu dispatches the uiMenuEvent.MENU_SELECT event when the end-user selects a menu item.

141
142
143
144
145
146

		private function on_menuSelect(evt:uiMenuEvent):void
		{
			displayText.text = "Label: "+evt.item.label+" has been selected";
			displayText.text += "\ngroup property value: "+evt.item.group;
			displayText.text += "\nchecked property value: "+evt.item.checked;
		}

See also: uiMenu usage notes

Aspire UI Components
Aspire UI is a library of Actionscript 3.0 (AS3) classes for building flexible and lightweight UI elements in Adobe Flash applications. Key features include easy skinning using PNG image files, automatic tab focus ordering, CSS text styles, and layout management. This is a pure AS3 library with no dependency on the Flex framework. You may experiment with the various features by downloading a trial version at
http://ghostwire.com/aspireui/download/